#include make_win.inc

print (1)'eventmask'($00100000$)

#define PUSH_BUTTON(Variable) FnEvent("push button operated",Variable$)

Done=0,
:   Button_on_top=1

EventMask1$=FnWindow_Class$("getmask","First_Win,")
EventMask2$=ior(EventMask1$,$00000100$)

repeat
Event=FnEvent_Code("")

switch Event
case PUSH_BUTTON(Button1);
:       gosub clear_event;
:       if Button_on_Top then
:           Result$=FnButton_Class$("move","First Button,0,40,");
:           Button_on_Top=0
:       else
:           Result$=FnButton_Class$("move","First Button,0,0,");
:           Button_On_Top=1
:       fi;
:       break
case PUSH_BUTTON(Button2);
:       gosub clear_event;
:       Result$=FnButton_Class$("hide","First Button,");
:       Result$=FnTool_Button_Class$("hide","First Tool Button,");
:       Result$=FnTool_Button_Class$("hide","Second Tool Button,");
:       Result$=FnWindow_Class$("setmask","First_Win,"
:           +hta(EventMask2$));
:       print (1)'eventmask'(EventMask2$);
:       break
case PUSH_BUTTON(Button3);
:       gosub clear_event;
:       Result$=FnButton_Class$("show","First Button,");
:       Result$=FnTool_Button_Class$("show","First Tool Button,");
:       Result$=FnTool_Button_Class$("show","Second Tool Button,");
:       Result$=FnWindow_Class$("setmask","First_Win,"
:           +hta(EventMask1$));
:       print (1)'eventmask'(EventMask1$);
:       break
case FnEvent("mouse moved",First_Window$+$0000$);
:       gosub clear_event;
:       gosub Toggle_Images;
:       break
case FnEvent("scrollbar position changed",Datebox1$);
:       gosub clear_event;
:       gosub Update_Datebox;
:       break
case FnEvent("close box operated",First_Window$+$0000$);
:       gosub clear_event;
:       Done=1;
:       break
swend

until Done
stop

Clear_Event:

Trash$=stbl("!CLEAR","$Sysgui_Event")
return

Toggle_Images:

dim        Mouse_Event$:tmpl(1)
Mouse_Event$=stbl("$Sysgui_Event")
if Mouse_Event.X<40 or Mouse_Event.X>120 or
:       Mouse_Event.Y<40 or Mouse_Event.Y>80 then
:           Result$=FnTool_Button_Class$("hide","First Tool Button,");
:           Result$=FnTool_Button_Class$("hide","Second Tool Button,");
:           return
if Mouse_Event.X<80 then
:       Result$=FnTool_Button_Class$("show","First Tool Button,");
:       Result$=FnTool_Button_Class$("hide","Second Tool Button,")
:   else
:       Result$=FnTool_Button_Class$("show","Second Tool Button,");
:       Result$=FnTool_Button_Class$("hide","First Tool Button,")
return

Update_Datebox:

Event$=stbl("$Sysgui_Event")
Result$=FnDatebox_Class$("scroll","First Datebox,"
:       +str(dec(Event$(4,2)))+","+Base_Date$)

return

#include sysgui.cls
#include window.cls
#include button.cls
#include tbutton.cls
#include datebox.cls 
end